home *** CD-ROM | disk | FTP | other *** search
/ Programming Languages Suite / ProgramD2.iso / Database Designers / Rational Rose 2000 / Rational Setup.EXE / common / lib / Data / Dumper.pm
Text File  |  1999-01-25  |  29KB  |  964 lines
  1. #
  2. # Data/Dumper.pm
  3. #
  4. # convert perl data structures into perl syntax suitable for both printing
  5. # and eval
  6. #
  7. # Documentation at the __END__
  8. #
  9.  
  10. package Data::Dumper;
  11.  
  12. $VERSION = $VERSION = '2.09';
  13.  
  14. #$| = 1;
  15.  
  16. require 5.004;
  17. require Exporter;
  18. require DynaLoader;
  19. require overload;
  20.  
  21. use Carp;
  22.  
  23. @ISA = qw(Exporter DynaLoader);
  24. @EXPORT = qw(Dumper);
  25. @EXPORT_OK = qw(DumperX);
  26.  
  27. bootstrap Data::Dumper;
  28.  
  29. # module vars and their defaults
  30. $Indent = 2 unless defined $Indent;
  31. $Purity = 0 unless defined $Purity;
  32. $Pad = "" unless defined $Pad;
  33. $Varname = "VAR" unless defined $Varname;
  34. $Useqq = 0 unless defined $Useqq;
  35. $Terse = 0 unless defined $Terse;
  36. $Freezer = "" unless defined $Freezer;
  37. $Toaster = "" unless defined $Toaster;
  38. $Deepcopy = 0 unless defined $Deepcopy;
  39. $Quotekeys = 1 unless defined $Quotekeys;
  40. $Bless = "bless" unless defined $Bless;
  41. #$Expdepth = 0 unless defined $Expdepth;
  42. #$Maxdepth = 0 unless defined $Maxdepth;
  43.  
  44. #
  45. # expects an arrayref of values to be dumped.
  46. # can optionally pass an arrayref of names for the values.
  47. # names must have leading $ sign stripped. begin the name with *
  48. # to cause output of arrays and hashes rather than refs.
  49. #
  50. sub new {
  51.   my($c, $v, $n) = @_;
  52.  
  53.   croak "Usage:  PACKAGE->new(ARRAYREF, [ARRAYREF])" 
  54.     unless (defined($v) && (ref($v) eq 'ARRAY'));
  55.   $n = [] unless (defined($n) && (ref($v) eq 'ARRAY'));
  56.  
  57.   my($s) = { 
  58.              level      => 0,           # current recursive depth
  59.          indent     => $Indent,     # various styles of indenting
  60.          pad    => $Pad,        # all lines prefixed by this string
  61.          xpad       => "",          # padding-per-level
  62.          apad       => "",          # added padding for hash keys n such
  63.          sep        => "",          # list separator
  64.          seen       => {},          # local (nested) refs (id => [name, val])
  65.          todump     => $v,          # values to dump []
  66.          names      => $n,          # optional names for values []
  67.          varname    => $Varname,    # prefix to use for tagging nameless ones
  68.              purity     => $Purity,     # degree to which output is evalable
  69.              useqq     => $Useqq,      # use "" for strings (backslashitis ensues)
  70.              terse     => $Terse,      # avoid name output (where feasible)
  71.              freezer    => $Freezer,    # name of Freezer method for objects
  72.              toaster    => $Toaster,    # name of method to revive objects
  73.              deepcopy    => $Deepcopy,   # dont cross-ref, except to stop recursion
  74.              quotekeys    => $Quotekeys,  # quote hash keys
  75.              'bless'    => $Bless,    # keyword to use for "bless"
  76. #         expdepth   => $Expdepth,   # cutoff depth for explicit dumping
  77. #         maxdepth    => $Maxdepth,   # depth beyond which we give up
  78.        };
  79.  
  80.   if ($Indent > 0) {
  81.     $s->{xpad} = "  ";
  82.     $s->{sep} = "\n";
  83.   }
  84.   return bless($s, $c);
  85. }
  86.  
  87. #
  88. # add-to or query the table of already seen references
  89. #
  90. sub Seen {
  91.   my($s, $g) = @_;
  92.   if (defined($g) && (ref($g) eq 'HASH'))  {
  93.     my($k, $v, $id);
  94.     while (($k, $v) = each %$g) {
  95.       if (defined $v and ref $v) {
  96.     ($id) = (overload::StrVal($v) =~ /\((.*)\)$/);
  97.     if ($k =~ /^[*](.*)$/) {
  98.       $k = (ref $v eq 'ARRAY') ? ( "\\\@" . $1 ) :
  99.            (ref $v eq 'HASH')  ? ( "\\\%" . $1 ) :
  100.            (ref $v eq 'CODE')  ? ( "\\\&" . $1 ) :
  101.                      (   "\$" . $1 ) ;
  102.     }
  103.     elsif ($k !~ /^\$/) {
  104.       $k = "\$" . $k;
  105.     }
  106.     $s->{seen}{$id} = [$k, $v];
  107.       }
  108.       else {
  109.     carp "Only refs supported, ignoring non-ref item \$$k";
  110.       }
  111.     }
  112.     return $s;
  113.   }
  114.   else {
  115.     return map { @$_ } values %{$s->{seen}};
  116.   }
  117. }
  118.  
  119. #
  120. # set or query the values to be dumped
  121. #
  122. sub Values {
  123.   my($s, $v) = @_;
  124.   if (defined($v) && (ref($v) eq 'ARRAY'))  {
  125.     $s->{todump} = [@$v];        # make a copy
  126.     return $s;
  127.   }
  128.   else {
  129.     return @{$s->{todump}};
  130.   }
  131. }
  132.  
  133. #
  134. # set or query the names of the values to be dumped
  135. #
  136. sub Names {
  137.   my($s, $n) = @_;
  138.   if (defined($n) && (ref($n) eq 'ARRAY'))  {
  139.     $s->{names} = [@$n];         # make a copy
  140.     return $s;
  141.   }
  142.   else {
  143.     return @{$s->{names}};
  144.   }
  145. }
  146.  
  147. sub DESTROY {}
  148.  
  149. #
  150. # dump the refs in the current dumper object.
  151. # expects same args as new() if called via package name.
  152. #
  153. sub Dump {
  154.   my($s) = shift;
  155.   my(@out, $val, $name);
  156.   my($i) = 0;
  157.   local(@post);
  158.  
  159.   $s = $s->new(@_) unless ref $s;
  160.  
  161.   for $val (@{$s->{todump}}) {
  162.     my $out = "";
  163.     @post = ();
  164.     $name = $s->{names}[$i++];
  165.     if (defined $name) {
  166.       if ($name =~ /^[*](.*)$/) {
  167.     if (defined $val) {
  168.       $name = (ref $val eq 'ARRAY') ? ( "\@" . $1 ) :
  169.           (ref $val eq 'HASH')  ? ( "\%" . $1 ) :
  170.           (ref $val eq 'CODE')  ? ( "\*" . $1 ) :
  171.                       ( "\$" . $1 ) ;
  172.     }
  173.     else {
  174.       $name = "\$" . $1;
  175.     }
  176.       }
  177.       elsif ($name !~ /^\$/) {
  178.     $name = "\$" . $name;
  179.       }
  180.     }
  181.     else {
  182.       $name = "\$" . $s->{varname} . $i;
  183.     }
  184.  
  185.     my $valstr;
  186.     {
  187.       local($s->{apad}) = $s->{apad};
  188.       $s->{apad} .= ' ' x (length($name) + 3) if $s->{indent} >= 2;
  189.       $valstr = $s->_dump($val, $name);
  190.     }
  191.  
  192.     $valstr = "$name = " . $valstr . ';' if @post or !$s->{terse};
  193.     $out .= $s->{pad} . $valstr . $s->{sep};
  194.     $out .= $s->{pad} . join(';' . $s->{sep} . $s->{pad}, @post) 
  195.       . ';' . $s->{sep} if @post;
  196.  
  197.     push @out, $out;
  198.   }
  199.   return wantarray ? @out : join('', @out);
  200. }
  201.  
  202. #
  203. # twist, toil and turn;
  204. # and recurse, of course.
  205. #
  206. sub _dump {
  207.   my($s, $val, $name) = @_;
  208.   my($sname);
  209.   my($out, $realpack, $realtype, $type, $ipad, $id, $blesspad);
  210.  
  211.   return "undef" unless defined $val;
  212.  
  213.   $type = ref $val;
  214.   $out = "";
  215.  
  216.   if ($type) {
  217.  
  218.     # prep it, if it looks like an object
  219.     if ($type =~ /[a-z_:]/) {
  220.       my $freezer = $s->{freezer};
  221.       # UNIVERSAL::can should be used here, when we can require 5.004
  222.       if ($freezer) {
  223.     eval { $val->$freezer() };
  224.     carp "WARNING(Freezer method call failed): $@" if $@;
  225.       }
  226.     }
  227.  
  228.     ($realpack, $realtype, $id) =
  229.       (overload::StrVal($val) =~ /^(?:(.*)\=)?([^=]*)\(([^\(]*)\)$/);
  230.     
  231.     # keep a tab on it so that we dont fall into recursive pit
  232.     if (exists $s->{seen}{$id}) {
  233. #     if ($s->{expdepth} < $s->{level}) {
  234.       if ($s->{purity} and $s->{level} > 0) {
  235.     $out = ($realtype eq 'HASH')  ? '{}' :
  236.            ($realtype eq 'ARRAY') ? '[]' :
  237.                     "''" ;
  238.       push @post, $name . " = " . $s->{seen}{$id}[0];
  239.       }
  240.       else {
  241.     $out = $s->{seen}{$id}[0];
  242.     if ($name =~ /^([\@\%])/) {
  243.       my $start = $1;
  244.       if ($out =~ /^\\$start/) {
  245.         $out = substr($out, 1);
  246.       }
  247.       else {
  248.         $out = $start . '{' . $out . '}';
  249.       }
  250.     }
  251.       }
  252.       return $out;
  253. #     }
  254.     }
  255.     else {
  256.       # store our name
  257.       $s->{seen}{$id} = [ (($name =~ /^[@%]/)     ? ('\\' . $name ) :
  258.                ($realtype eq 'CODE' and
  259.                 $name =~ /^[*](.*)$/) ? ('\\&' . $1 )   :
  260.                              $name          ),
  261.               $val ];
  262.     }
  263.  
  264.     $s->{level}++;
  265.     $ipad = $s->{xpad} x $s->{level};
  266.  
  267.     if ($realpack) {          # we have a blessed ref
  268.       $out = $s->{'bless'} . '( ';
  269.       $blesspad = $s->{apad};
  270.       $s->{apad} .= '       ' if ($s->{indent} >= 2);
  271.     }
  272.     
  273.     if ($realtype eq 'SCALAR') {
  274.       if ($realpack) {
  275.     $out .= 'do{\\(my $o = ' . $s->_dump($$val, "") . ')}';
  276.       }
  277.       else {
  278.     $out .= '\\' . $s->_dump($$val, "");
  279.       }
  280.     }
  281.     elsif ($realtype eq 'GLOB') {
  282.     $out .= '\\' . $s->_dump($$val, "");
  283.     }
  284.     elsif ($realtype eq 'ARRAY') {
  285.       my($v, $pad, $mname);
  286.       my($i) = 0;
  287.       $out .= ($name =~ /^\@/) ? '(' : '[';
  288.       $pad = $s->{sep} . $s->{pad} . $s->{apad};
  289.       ($name =~ /^\@(.*)$/) ? ($mname = "\$" . $1) : 
  290.     ($name =~ /[]}]$/) ? ($mname = $name) : ($mname = $name . '->');
  291.       $mname .= '->' if $mname =~ /^\*.+\{[A-Z]+\}$/;
  292.       for $v (@$val) {
  293.     $sname = $mname . '[' . $i . ']';
  294.     $out .= $pad . $ipad . '#' . $i if $s->{indent} >= 3;
  295.     $out .= $pad . $ipad . $s->_dump($v, $sname);
  296.     $out .= "," if $i++ < $#$val;
  297.       }
  298.       $out .= $pad . ($s->{xpad} x ($s->{level} - 1)) if $i;
  299.       $out .= ($name =~ /^\@/) ? ')' : ']';
  300.     }
  301.     elsif ($realtype eq 'HASH') {
  302.       my($k, $v, $pad, $lpad, $mname);
  303.       $out .= ($name =~ /^\%/) ? '(' : '{';
  304.       $pad = $s->{sep} . $s->{pad} . $s->{apad};
  305.       $lpad = $s->{apad};
  306.       ($name =~ /^\%(.*)$/) ? ($mname = "\$" . $1) : 
  307.     ($name =~ /[]}]$/) ? ($mname = $name) : ($mname = $name . '->');
  308.       $mname .= '->' if $mname =~ /^\*.+\{[A-Z]+\}$/;
  309.       while (($k, $v) = each %$val) {
  310.     my $nk = $s->_dump($k, "");
  311.     $nk = $1 if !$s->{quotekeys} and $nk =~ /^[\"\']([A-Za-z_]\w*)[\"\']$/;
  312.     $sname = $mname . '{' . $nk . '}';
  313.     $out .= $pad . $ipad . $nk . " => ";
  314.  
  315.     # temporarily alter apad
  316.     $s->{apad} .= (" " x (length($nk) + 4)) if $s->{indent} >= 2;
  317.     $out .= $s->_dump($val->{$k}, $sname) . ",";
  318.     $s->{apad} = $lpad if $s->{indent} >= 2;
  319.       }
  320.       if (substr($out, -1) eq ',') {
  321.     chop $out;
  322.     $out .= $pad . ($s->{xpad} x ($s->{level} - 1));
  323.       }
  324.       $out .= ($name =~ /^\%/) ? ')' : '}';
  325.     }
  326.     elsif ($realtype eq 'CODE') {
  327.       $out .= '"DUMMY"';
  328.       $out = 'sub { ' . $out . ' }';
  329.       carp "Encountered CODE ref, using dummy placeholder" if $s->{purity};
  330.     }
  331.     else {
  332.       croak "Can\'t handle $realtype type.";
  333.     }
  334.     
  335.     if ($realpack) { # we have a blessed ref
  336.       $out .= ', \'' . $realpack . '\'' . ' )';
  337.       $out .= '->' . $s->{toaster} . '()'  if $s->{toaster} ne '';
  338.       $s->{apad} = $blesspad;
  339.     }
  340.     $s->{level}--;
  341.  
  342.   }
  343.   else {                                 # simple scalar
  344.  
  345.     my $ref = \$_[1];
  346.     # first, catalog the scalar
  347.     if ($name ne '') {
  348.       ($id) = ("$ref" =~ /\(([^\(]*)\)$/);
  349.       if (exists $s->{seen}{$id}) {
  350.     $out = $s->{seen}{$id}[0];
  351.     return $out;
  352.       }
  353.       else {
  354.     $s->{seen}{$id} = ["\\$name", $val];
  355.       }
  356.     }
  357.     if (ref($ref) eq 'GLOB' or "$ref" =~ /=GLOB\([^()]+\)$/) {  # glob
  358.       my $name = substr($val, 1);
  359.       if ($name =~ /^[A-Za-z_][\w:]*$/) {
  360.     $name =~ s/^main::/::/;
  361.     $sname = $name;
  362.       }
  363.       else {
  364.     $sname = $s->_dump($name, "");
  365.     $sname = '{' . $sname . '}';
  366.       }
  367.       if ($s->{purity}) {
  368.     my $k;
  369.     local ($s->{level}) = 0;
  370.     for $k (qw(SCALAR ARRAY HASH)) {
  371.       # _dump can push into @post, so we hold our place using $postlen
  372.       my $postlen = scalar @post;
  373.       $post[$postlen] = "\*$sname = ";
  374.       local ($s->{apad}) = " " x length($post[$postlen]) if $s->{indent} >= 2;
  375.       $post[$postlen] .= $s->_dump(*{$name}{$k}, "\*$sname\{$k\}");
  376.     }
  377.       }
  378.       $out .= '*' . $sname;
  379.     }
  380.     elsif ($val =~ /^-?[1-9]\d{0,8}$/) { # safe decimal number
  381.       $out .= $val;
  382.     }
  383.     else {                 # string
  384.       if ($s->{useqq}) {
  385.     $out .= qquote($val);
  386.       }
  387.       else {
  388.     $val =~ s/([\\\'])/\\$1/g;
  389.     $out .= '\'' . $val .  '\'';
  390.       }
  391.     }
  392.   }
  393.  
  394.   # if we made it this far, $id was added to seen list at current
  395.   # level, so remove it to get deep copies
  396.   delete($s->{seen}{$id}) if $id and $s->{deepcopy};
  397.   return $out;
  398. }
  399.   
  400. #
  401. # non-OO style of earlier version
  402. #
  403. sub Dumper {
  404.   return Data::Dumper->Dump([@_]);
  405. }
  406.  
  407. #
  408. # same, only calls the XS version
  409. #
  410. sub DumperX {
  411.   return Data::Dumper->Dumpxs([@_], []);
  412. }
  413.  
  414. sub Dumpf { return Data::Dumper->Dump(@_) }
  415.  
  416. sub Dumpp { print Data::Dumper->Dump(@_) }
  417.  
  418. #
  419. # reset the "seen" cache 
  420. #
  421. sub Reset {
  422.   my($s) = shift;
  423.   $s->{seen} = {};
  424.   return $s;
  425. }
  426.  
  427. sub Indent {
  428.   my($s, $v) = @_;
  429.   if (defined($v)) {
  430.     if ($v == 0) {
  431.       $s->{xpad} = "";
  432.       $s->{sep} = "";
  433.     }
  434.     else {
  435.       $s->{xpad} = "  ";
  436.       $s->{sep} = "\n";
  437.     }
  438.     $s->{indent} = $v;
  439.     return $s;
  440.   }
  441.   else {
  442.     return $s->{indent};
  443.   }
  444. }
  445.  
  446. sub Pad {
  447.   my($s, $v) = @_;
  448.   defined($v) ? (($s->{pad} = $v), return $s) : $s->{pad};
  449. }
  450.  
  451. sub Varname {
  452.   my($s, $v) = @_;
  453.   defined($v) ? (($s->{varname} = $v), return $s) : $s->{varname};
  454. }
  455.  
  456. sub Purity {
  457.   my($s, $v) = @_;
  458.   defined($v) ? (($s->{purity} = $v), return $s) : $s->{purity};
  459. }
  460.  
  461. sub Useqq {
  462.   my($s, $v) = @_;
  463.   defined($v) ? (($s->{useqq} = $v), return $s) : $s->{useqq};
  464. }
  465.  
  466. sub Terse {
  467.   my($s, $v) = @_;
  468.   defined($v) ? (($s->{terse} = $v), return $s) : $s->{terse};
  469. }
  470.  
  471. sub Freezer {
  472.   my($s, $v) = @_;
  473.   defined($v) ? (($s->{freezer} = $v), return $s) : $s->{freezer};
  474. }
  475.  
  476. sub Toaster {
  477.   my($s, $v) = @_;
  478.   defined($v) ? (($s->{toaster} = $v), return $s) : $s->{toaster};
  479. }
  480.  
  481. sub Deepcopy {
  482.   my($s, $v) = @_;
  483.   defined($v) ? (($s->{deepcopy} = $v), return $s) : $s->{deepcopy};
  484. }
  485.  
  486. sub Quotekeys {
  487.   my($s, $v) = @_;
  488.   defined($v) ? (($s->{quotekeys} = $v), return $s) : $s->{quotekeys};
  489. }
  490.  
  491. sub Bless {
  492.   my($s, $v) = @_;
  493.   defined($v) ? (($s->{'bless'} = $v), return $s) : $s->{'bless'};
  494. }
  495.  
  496. # put a string value in double quotes
  497. sub qquote {
  498.   local($_) = shift;
  499.   s/([\\\"\@\$\%])/\\$1/g;    
  500.   s/\a/\\a/g;
  501.   s/[\b]/\\b/g;
  502.   s/\t/\\t/g;
  503.   s/\n/\\n/g;
  504.   s/\f/\\f/g;
  505.   s/\r/\\r/g;
  506.   s/\e/\\e/g;
  507.  
  508. # this won't work!
  509. #  s/([^\a\b\t\n\f\r\e\038-\176])/'\\'.sprintf('%03o',ord($1))/eg;
  510.   s/([\000-\006\013\016-\032\034-\037\177\200-\377])/'\\'.sprintf('%03o',ord($1))/eg;
  511.   return "\"$_\"";
  512. }
  513.  
  514. 1;
  515. __END__
  516.  
  517. =head1 NAME
  518.  
  519. Data::Dumper - stringified perl data structures, suitable for both printing and C<eval>
  520.  
  521.  
  522. =head1 SYNOPSIS
  523.  
  524.     use Data::Dumper;
  525.  
  526.     # simple procedural interface
  527.     print Dumper($foo, $bar);
  528.  
  529.     # extended usage with names
  530.     print Data::Dumper->Dump([$foo, $bar], [qw(foo *ary)]);
  531.  
  532.     # configuration variables
  533.     {
  534.       local $Data::Dump::Purity = 1;
  535.       eval Data::Dumper->Dump([$foo, $bar], [qw(foo *ary)]);
  536.     }
  537.  
  538.     # OO usage
  539.     $d = Data::Dumper->new([$foo, $bar], [qw(foo *ary)]);
  540.        ...
  541.     print $d->Dump;
  542.        ...
  543.     $d->Purity(1)->Terse(1)->Deepcopy(1);
  544.     eval $d->Dump;
  545.  
  546.  
  547. =head1 DESCRIPTION
  548.  
  549. Given a list of scalars or reference variables, writes out their contents in
  550. perl syntax. The references can also be objects.  The contents of each
  551. variable is output in a single Perl statement.  Handles self-referential
  552. structures correctly.
  553.  
  554. The return value can be C<eval>ed to get back an identical copy of the
  555. original reference structure.
  556.  
  557. Any references that are the same as one of those passed in will be named
  558. C<$VAR>I<n> (where I<n> is a numeric suffix), and other duplicate references
  559. to substructures within C<$VAR>I<n> will be appropriately labeled using arrow
  560. notation.  You can specify names for individual values to be dumped if you
  561. use the C<Dump()> method, or you can change the default C<$VAR> prefix to
  562. something else.  See C<$Data::Dumper::Varname> and C<$Data::Dumper::Terse>
  563. below.
  564.  
  565. The default output of self-referential structures can be C<eval>ed, but the
  566. nested references to C<$VAR>I<n> will be undefined, since a recursive
  567. structure cannot be constructed using one Perl statement.  You should set the
  568. C<Purity> flag to 1 to get additional statements that will correctly fill in
  569. these references.
  570.  
  571. In the extended usage form, the references to be dumped can be given
  572. user-specified names.  If a name begins with a C<*>, the output will 
  573. describe the dereferenced type of the supplied reference for hashes and
  574. arrays, and coderefs.  Output of names will be avoided where possible if
  575. the C<Terse> flag is set.
  576.  
  577. In many cases, methods that are used to set the internal state of the
  578. object will return the object itself, so method calls can be conveniently
  579. chained together.
  580.  
  581. Several styles of output are possible, all controlled by setting
  582. the C<Indent> flag.  See L<Configuration Variables or Methods> below 
  583. for details.
  584.  
  585.  
  586. =head2 Methods
  587.  
  588. =over 4
  589.  
  590. =item I<PACKAGE>->new(I<ARRAYREF [>, I<ARRAYREF]>)
  591.  
  592. Returns a newly created C<Data::Dumper> object.  The first argument is an
  593. anonymous array of values to be dumped.  The optional second argument is an
  594. anonymous array of names for the values.  The names need not have a leading
  595. C<$> sign, and must be comprised of alphanumeric characters.  You can begin
  596. a name with a C<*> to specify that the dereferenced type must be dumped
  597. instead of the reference itself, for ARRAY and HASH references.
  598.  
  599. The prefix specified by C<$Data::Dumper::Varname> will be used with a
  600. numeric suffix if the name for a value is undefined.
  601.  
  602. Data::Dumper will catalog all references encountered while dumping the
  603. values. Cross-references (in the form of names of substructures in perl
  604. syntax) will be inserted at all possible points, preserving any structural
  605. interdependencies in the original set of values.  Structure traversal is
  606. depth-first,  and proceeds in order from the first supplied value to
  607. the last.
  608.  
  609. =item I<$OBJ>->Dump  I<or>  I<PACKAGE>->Dump(I<ARRAYREF [>, I<ARRAYREF]>)
  610.  
  611. Returns the stringified form of the values stored in the object (preserving
  612. the order in which they were supplied to C<new>), subject to the
  613. configuration options below.  In an array context, it returns a list
  614. of strings corresponding to the supplied values.
  615.  
  616. The second form, for convenience, simply calls the C<new> method on its
  617. arguments before dumping the object immediately.
  618.  
  619. =item I<$OBJ>->Dumpxs  I<or>  I<PACKAGE>->Dumpxs(I<ARRAYREF [>, I<ARRAYREF]>)
  620.  
  621. This method is available if you were able to compile and install the XSUB
  622. extension to C<Data::Dumper>. It is exactly identical to the C<Dump> method 
  623. above, only about 4 to 5 times faster, since it is written entirely in C.
  624.  
  625. =item I<$OBJ>->Seen(I<[HASHREF]>)
  626.  
  627. Queries or adds to the internal table of already encountered references.
  628. You must use C<Reset> to explicitly clear the table if needed.  Such
  629. references are not dumped; instead, their names are inserted wherever they
  630. are encountered subsequently.  This is useful especially for properly
  631. dumping subroutine references.
  632.  
  633. Expects a anonymous hash of name => value pairs.  Same rules apply for names
  634. as in C<new>.  If no argument is supplied, will return the "seen" list of
  635. name => value pairs, in an array context.  Otherwise, returns the object
  636. itself.
  637.  
  638. =item I<$OBJ>->Values(I<[ARRAYREF]>)
  639.  
  640. Queries or replaces the internal array of values that will be dumped.
  641. When called without arguments, returns the values.  Otherwise, returns the
  642. object itself.
  643.  
  644. =item I<$OBJ>->Names(I<[ARRAYREF]>)
  645.  
  646. Queries or replaces the internal array of user supplied names for the values
  647. that will be dumped.  When called without arguments, returns the names.
  648. Otherwise, returns the object itself.
  649.  
  650. =item I<$OBJ>->Reset
  651.  
  652. Clears the internal table of "seen" references and returns the object
  653. itself.
  654.  
  655. =back
  656.  
  657. =head2 Functions
  658.  
  659. =over 4
  660.  
  661. =item Dumper(I<LIST>)
  662.  
  663. Returns the stringified form of the values in the list, subject to the
  664. configuration options below.  The values will be named C<$VAR>I<n> in the
  665. output, where I<n> is a numeric suffix.  Will return a list of strings
  666. in an array context.
  667.  
  668. =item DumperX(I<LIST>)
  669.  
  670. Identical to the C<Dumper()> function above, but this calls the XSUB 
  671. implementation.  Only available if you were able to compile and install
  672. the XSUB extensions in C<Data::Dumper>.
  673.  
  674. =back
  675.  
  676. =head2 Configuration Variables or Methods
  677.  
  678. Several configuration variables can be used to control the kind of output
  679. generated when using the procedural interface.  These variables are usually
  680. C<local>ized in a block so that other parts of the code are not affected by
  681. the change.  
  682.  
  683. These variables determine the default state of the object created by calling
  684. the C<new> method, but cannot be used to alter the state of the object
  685. thereafter.  The equivalent method names should be used instead to query
  686. or set the internal state of the object.
  687.  
  688. The method forms return the object itself when called with arguments,
  689. so that they can be chained together nicely.
  690.  
  691. =over 4
  692.  
  693. =item $Data::Dumper::Indent  I<or>  I<$OBJ>->Indent(I<[NEWVAL]>)
  694.  
  695. Controls the style of indentation.  It can be set to 0, 1, 2 or 3.  Style 0
  696. spews output without any newlines, indentation, or spaces between list
  697. items.  It is the most compact format possible that can still be called
  698. valid perl.  Style 1 outputs a readable form with newlines but no fancy
  699. indentation (each level in the structure is simply indented by a fixed
  700. amount of whitespace).  Style 2 (the default) outputs a very readable form
  701. which takes into account the length of hash keys (so the hash value lines
  702. up).  Style 3 is like style 2, but also annotates the elements of arrays
  703. with their index (but the comment is on its own line, so array output
  704. consumes twice the number of lines).  Style 2 is the default.
  705.  
  706. =item $Data::Dumper::Purity  I<or>  I<$OBJ>->Purity(I<[NEWVAL]>)
  707.  
  708. Controls the degree to which the output can be C<eval>ed to recreate the
  709. supplied reference structures.  Setting it to 1 will output additional perl
  710. statements that will correctly recreate nested references.  The default is
  711. 0.
  712.  
  713. =item $Data::Dumper::Pad  I<or>  I<$OBJ>->Pad(I<[NEWVAL]>)
  714.  
  715. Specifies the string that will be prefixed to every line of the output.
  716. Empty string by default.
  717.  
  718. =item $Data::Dumper::Varname  I<or>  I<$OBJ>->Varname(I<[NEWVAL]>)
  719.  
  720. Contains the prefix to use for tagging variable names in the output. The
  721. default is "VAR".
  722.  
  723. =item $Data::Dumper::Useqq  I<or>  I<$OBJ>->Useqq(I<[NEWVAL]>)
  724.  
  725. When set, enables the use of double quotes for representing string values.
  726. Whitespace other than space will be represented as C<[\n\t\r]>, "unsafe"
  727. characters will be backslashed, and unprintable characters will be output as
  728. quoted octal integers.  Since setting this variable imposes a performance
  729. penalty, the default is 0.  The C<Dumpxs()> method does not honor this
  730. flag yet.
  731.  
  732. =item $Data::Dumper::Terse  I<or>  I<$OBJ>->Terse(I<[NEWVAL]>)
  733.  
  734. When set, Data::Dumper will emit single, non-self-referential values as
  735. atoms/terms rather than statements.  This means that the C<$VAR>I<n> names
  736. will be avoided where possible, but be advised that such output may not
  737. always be parseable by C<eval>.
  738.  
  739. =item $Data::Dumper::Freezer  I<or>  $I<OBJ>->Freezer(I<[NEWVAL]>)
  740.  
  741. Can be set to a method name, or to an empty string to disable the feature.
  742. Data::Dumper will invoke that method via the object before attempting to
  743. stringify it.  This method can alter the contents of the object (if, for
  744. instance, it contains data allocated from C), and even rebless it in a
  745. different package.  The client is responsible for making sure the specified
  746. method can be called via the object, and that the object ends up containing
  747. only perl data types after the method has been called.  Defaults to an empty
  748. string.
  749.  
  750. =item $Data::Dumper::Toaster  I<or>  $I<OBJ>->Toaster(I<[NEWVAL]>)
  751.  
  752. Can be set to a method name, or to an empty string to disable the feature.
  753. Data::Dumper will emit a method call for any objects that are to be dumped
  754. using the syntax C<bless(DATA, CLASS)->METHOD()>.  Note that this means that
  755. the method specified will have to perform any modifications required on the
  756. object (like creating new state within it, and/or reblessing it in a
  757. different package) and then return it.  The client is responsible for making
  758. sure the method can be called via the object, and that it returns a valid
  759. object.  Defaults to an empty string.
  760.  
  761. =item $Data::Dumper::Deepcopy  I<or>  $I<OBJ>->Deepcopy(I<[NEWVAL]>)
  762.  
  763. Can be set to a boolean value to enable deep copies of structures.
  764. Cross-referencing will then only be done when absolutely essential
  765. (i.e., to break reference cycles).  Default is 0.
  766.  
  767. =item $Data::Dumper::Quotekeys  I<or>  $I<OBJ>->Quotekeys(I<[NEWVAL]>)
  768.  
  769. Can be set to a boolean value to control whether hash keys are quoted.
  770. A false value will avoid quoting hash keys when it looks like a simple
  771. string.  Default is 1, which will always enclose hash keys in quotes.
  772.  
  773. =item $Data::Dumper::Bless  I<or>  $I<OBJ>->Bless(I<[NEWVAL]>)
  774.  
  775. Can be set to a string that specifies an alternative to the C<bless>
  776. builtin operator used to create objects.  A function with the specified
  777. name should exist, and should accept the same arguments as the builtin.
  778. Default is C<bless>.
  779.  
  780. =back
  781.  
  782. =head2 Exports
  783.  
  784. =over 4
  785.  
  786. =item Dumper
  787.  
  788. =back
  789.  
  790. =head1 EXAMPLES
  791.  
  792. Run these code snippets to get a quick feel for the behavior of this
  793. module.  When you are through with these examples, you may want to
  794. add or change the various configuration variables described above,
  795. to see their behavior.  (See the testsuite in the Data::Dumper
  796. distribution for more examples.)
  797.  
  798.  
  799.     use Data::Dumper;
  800.  
  801.     package Foo;
  802.     sub new {bless {'a' => 1, 'b' => sub { return "foo" }}, $_[0]};
  803.  
  804.     package Fuz;                       # a weird REF-REF-SCALAR object
  805.     sub new {bless \($_ = \ 'fu\'z'), $_[0]};
  806.  
  807.     package main;
  808.     $foo = Foo->new;
  809.     $fuz = Fuz->new;
  810.     $boo = [ 1, [], "abcd", \*foo,
  811.              {1 => 'a', 023 => 'b', 0x45 => 'c'}, 
  812.              \\"p\q\'r", $foo, $fuz];
  813.     
  814.     ########
  815.     # simple usage
  816.     ########
  817.  
  818.     $bar = eval(Dumper($boo));
  819.     print($@) if $@;
  820.     print Dumper($boo), Dumper($bar);  # pretty print (no array indices)
  821.  
  822.     $Data::Dumper::Terse = 1;          # don't output names where feasible
  823.     $Data::Dumper::Indent = 0;         # turn off all pretty print
  824.     print Dumper($boo), "\n";
  825.  
  826.     $Data::Dumper::Indent = 1;         # mild pretty print
  827.     print Dumper($boo);
  828.  
  829.     $Data::Dumper::Indent = 3;         # pretty print with array indices
  830.     print Dumper($boo);
  831.  
  832.     $Data::Dumper::Useqq = 1;          # print strings in double quotes
  833.     print Dumper($boo);
  834.     
  835.     
  836.     ########
  837.     # recursive structures
  838.     ########
  839.     
  840.     @c = ('c');
  841.     $c = \@c;
  842.     $b = {};
  843.     $a = [1, $b, $c];
  844.     $b->{a} = $a;
  845.     $b->{b} = $a->[1];
  846.     $b->{c} = $a->[2];
  847.     print Data::Dumper->Dump([$a,$b,$c], [qw(a b c)]);
  848.     
  849.     
  850.     $Data::Dumper::Purity = 1;         # fill in the holes for eval
  851.     print Data::Dumper->Dump([$a, $b], [qw(*a b)]); # print as @a
  852.     print Data::Dumper->Dump([$b, $a], [qw(*b a)]); # print as %b
  853.     
  854.     
  855.     $Data::Dumper::Deepcopy = 1;       # avoid cross-refs
  856.     print Data::Dumper->Dump([$b, $a], [qw(*b a)]);
  857.     
  858.     
  859.     $Data::Dumper::Purity = 0;         # avoid cross-refs
  860.     print Data::Dumper->Dump([$b, $a], [qw(*b a)]);
  861.     
  862.     
  863.     ########
  864.     # object-oriented usage
  865.     ########
  866.     
  867.     $d = Data::Dumper->new([$a,$b], [qw(a b)]);
  868.     $d->Seen({'*c' => $c});            # stash a ref without printing it
  869.     $d->Indent(3);
  870.     print $d->Dump;
  871.     $d->Reset->Purity(0);              # empty the seen cache
  872.     print join "----\n", $d->Dump;
  873.     
  874.     
  875.     ########
  876.     # persistence
  877.     ########
  878.     
  879.     package Foo;
  880.     sub new { bless { state => 'awake' }, shift }
  881.     sub Freeze {
  882.         my $s = shift;
  883.     print STDERR "preparing to sleep\n";
  884.     $s->{state} = 'asleep';
  885.     return bless $s, 'Foo::ZZZ';
  886.     }
  887.     
  888.     package Foo::ZZZ;
  889.     sub Thaw {
  890.         my $s = shift;
  891.     print STDERR "waking up\n";
  892.     $s->{state} = 'awake';
  893.     return bless $s, 'Foo';
  894.     }
  895.     
  896.     package Foo;
  897.     use Data::Dumper;
  898.     $a = Foo->new;
  899.     $b = Data::Dumper->new([$a], ['c']);
  900.     $b->Freezer('Freeze');
  901.     $b->Toaster('Thaw');
  902.     $c = $b->Dump;
  903.     print $c;
  904.     $d = eval $c;
  905.     print Data::Dumper->Dump([$d], ['d']);
  906.     
  907.     
  908.     ########
  909.     # symbol substitution (useful for recreating CODE refs)
  910.     ########
  911.     
  912.     sub foo { print "foo speaking\n" }
  913.     *other = \&foo;
  914.     $bar = [ \&other ];
  915.     $d = Data::Dumper->new([\&other,$bar],['*other','bar']);
  916.     $d->Seen({ '*foo' => \&foo });
  917.     print $d->Dump;
  918.  
  919.  
  920. =head1 BUGS
  921.  
  922. Due to limitations of Perl subroutine call semantics, you cannot pass an
  923. array or hash.  Prepend it with a C<\> to pass its reference instead.  This
  924. will be remedied in time, with the arrival of prototypes in later versions
  925. of Perl.  For now, you need to use the extended usage form, and prepend the
  926. name with a C<*> to output it as a hash or array.
  927.  
  928. C<Data::Dumper> cheats with CODE references.  If a code reference is
  929. encountered in the structure being processed, an anonymous subroutine that
  930. contains the string '"DUMMY"' will be inserted in its place, and a warning
  931. will be printed if C<Purity> is set.  You can C<eval> the result, but bear
  932. in mind that the anonymous sub that gets created is just a placeholder.
  933. Someday, perl will have a switch to cache-on-demand the string
  934. representation of a compiled piece of code, I hope.  If you have prior
  935. knowledge of all the code refs that your data structures are likely
  936. to have, you can use the C<Seen> method to pre-seed the internal reference
  937. table and make the dumped output point to them, instead.  See L<EXAMPLES>
  938. above.
  939.  
  940. The C<Useqq> flag is not honored by C<Dumpxs()> (it always outputs
  941. strings in single quotes).
  942.  
  943. SCALAR objects have the weirdest looking C<bless> workaround.
  944.  
  945.  
  946. =head1 AUTHOR
  947.  
  948. Gurusamy Sarathy        gsar@umich.edu
  949.  
  950. Copyright (c) 1996-98 Gurusamy Sarathy. All rights reserved.
  951. This program is free software; you can redistribute it and/or
  952. modify it under the same terms as Perl itself.
  953.  
  954.  
  955. =head1 VERSION
  956.  
  957. Version 2.09    (9 July 1998)
  958.  
  959. =head1 SEE ALSO
  960.  
  961. perl(1)
  962.  
  963. =cut
  964.